#C14.txt

Help14:=proc(): print(`NuSYT(L), SYTpairs(n), NuSYTpairs(n)  `):
print(`IandB(a,i)`):
end:

#IandB(a,i): inputs a weakly-increasing sequence of pos. integers a,
#and an integer i puts it where i belongs, and bumps the
#one that used to be there. If it is larger than the members of i
#it does not bump anyone, and the output is a larger sequence
#with i at the end
IandB:=proc(a,i) local k,j:
k:=nops(a):
for j from 1 to nops(a) while a[j]<i do od:

if j=k+1 then
 RETURN([op(a),i],0):
 else
 RETURN([op(1..j-1,a),i,op(j+1..k,a)],a[j]):
 fi:
end:

NuSYT:=proc(L) local i:
option remember:

if min(op(L))<0 then
 RETURN(0):
fi:
if L=[0$nops(L)] then
   RETURN(1):
 fi:


if min(seq(L[i]-L[i+1],i=1..nops(L)-1))<0 then
  RETURN(0):
 fi:
add(NuSYT([op(1..i-1,L),L[i]-1,op(i+1..nops(L),L)]),i=1..nops(L)):
end:



#SYTpairs(n): The set of pairs of Standard Young Tableaux of the same shape
SYTpairs:=proc(n) local P,S,S1,p,s1,s2:
P:=Par(n):
S:={}:
for p in P do
 S1:=SYT(p):
 S:=S union {seq(seq([s1,s2],s1 in S1), s2 in S1)}:
 od:
S:
end:

#NuSYTpairs(n): The set of pairs of Standard Young Tableaux of the same shape
NuSYTpairs:=proc(n) local P,p:
P:=Par(n):
add(NuSYT(p)^2, p in P):
end:




###old stuff
Help13:=proc(): print(` PFG(L), SYT(L), PSYT(L) `): end:
Help12:=proc():
 print(`Park(n,k), Par(n), ParN(n,k)`):
end:



ParN:=proc(n,k) local s,S,T: S:=Par(n):T:={}:
for s in S do
 if s[1]=k then
  T:=T union {s}:
 fi:
od:
T:
end:
#Park(n,k): The set of partitions of n into exactly k parts
Park:=proc(n,k) local S,k1,S1,s1:
option remember:

if n<k then
   RETURN({}):
fi:

if k=0 then
 if n=0 then
   RETURN({[]}):
   else
    RETURN({}):
fi:
fi:

S:={}:
for k1 from 0 to k do
 S1:=Park(n-k,k1):
 S:= S union {seq([op(s1+[1$k1]),1$(k-k1)], s1 in S1)}:
od:
S:
end:


#Par(n): The set of partitions of n, the clever way.
Par:=proc(n) local k:
{seq(op(Park(n,k)), k=1..n)}:
end:

#PFG(L): The Ferrers graph of the partition L
PFG:=proc(L) local i:
for i from 1 to nops(L) do
lprint(1$L[i]):
od:
print(`----------------`):
end:




ParN:=proc(n,k) local s,S,T: S:=Par(n):T:={}:
for s in S do
 if s[1]=k then
  T:=T union {s}:
 fi:
od:
T:
end:

#Def. Standard Young tableau of shape L L=[3,3,2] a partition of 8
#
#111111
#111111
#11
#
#A way of filling {1, ..., 8} the empty boxes such that every row and every column are increasing
#
#L=[2,2]
#
#12
#34
#
#13
#24    Number of of YT of shape [2,2]
#
#Where can n (the tallest person) seat w/o disturbing shorter people
#

#SYT(L): The SET of Standard Young tableaux of shape L
SYT:=proc(L) local i, k,n,S,L1,S1,s1:
option remember:
k:=nops(L):
n:=add(L[i],i=1..k):
if k=0 then
  RETURN({[]}):
fi:
S:={}:
#Look for all legal rows where Mr. or Ms. n can place themselves
for i from 1 to k-1 do
if L[i]>L[i+1] then
 L1:=[op(1..i-1,L),L[i]-1,op(i+1..k,L)]:
 S1:=SYT(L1):

S:=S union {seq(
[op(1..i-1,s1),[op(s1[i]),n],op(i+1..k,s1)]
,s1  in S1)}:
fi:
od:

if L[k]>1 then
L1:=[op(1..k-1,L),L[k]-1]:

S1:=SYT(L1):
S:=S union {seq(
[op(1..k-1,s1),[op(s1[k]),n]]
,s1  in S1)}:
else
L1:=[op(1..k-1,L)]:
S1:=SYT(L1):
S:=S union {seq(
[op(1..k-1,s1), [n]]
,s1  in S1)}:
fi:
S:
end:

#PSYT(Y): prints the SYT Y
PSYT:=proc(Y) local i:
for i from 1 to nops(Y) do
lprint(op(Y[i])):
od:
end: