Help12:=proc(): print(`  Park(n,k), Par(n), A41s(N), A41ok(N), A41c(N), A41c1(n)  `): end:

#Park(n,k): The set of partitions of n into exactly k parts
Park:=proc(n,k) local S,k1,S1,s1:
option remember:

if n<k then
   RETURN({}):
fi:

if k=0 then
 if n=0 then
   RETURN({[]}):
   else
    RETURN({}):
fi:
fi:

S:={}:
for k1 from 0 to k do
 S1:=Park(n-k,k1):
 S:= S union {seq([op(s1+[1$k1]),1$(k-k1)], s1 in S1)}:
od:
S:
end:

#Par(n): The set of partitions of n, the clever way.
Par:=proc(n) local k:
{seq(op(Park(n,k)), k=1..n)}:
end:

#A41s(N): The first N terms of OEIS sequence A41 the stupid way
A41s:=proc(N) local n: [seq(nops(Par(n)),n=1..N)]:end:

A41ok:=proc(N) local f,q,n:
f:=mul(1/(1-q^n),n=1..N):
f:=taylor(f,q=0,N+1):
[seq(coeff(f,q,n),n=1..N)]:
end:

#A41c(N): The first N terms of OEIS sequence A41 the clever way (using the Euler recurrence
A41c:=proc(N) local n:
[seq(A41c1(n),n=1..N)]:
end:

#A41[n] the clever way, using the  Euler recurrence
A41c1:=proc(n) local j,co:
option remember:
if n<0 then
 RETURN(0):
fi:
if n=0 then
 RETURN(1):
fi:

co:=0:

for j from 1 while n-(3*j^2+j)/2 >=0 do
 co:=co-(-1)^j*A41c1(n-(3*j^2+j)/2)
od:

for j from 1 while n-(3*j^2-j)/2 >=0 do
 co:=co-(-1)^j*A41c1(n-(3*j^2-j)/2):
od:
co:
end: