#hw13JikeLiu
# Jike Liu

read `C13.txt`:

#-----------------------------------------------------------
#1. d-super-distinct partitions
#-----------------------------------------------------------

IsSuperDistinct:=proc(L,d) local i:
for i from 1 to nops(L)-1 do
 if L[i]-L[i+1] < d then
  RETURN(false):
 fi:
od:
true:
end:

SuperDistinctPars:=proc(n,d) local S,T,s:
S:=Par(n): T:={}:
for s in S do
 if IsSuperDistinct(s,d) then
  T:=T union {s}:
 fi:
od:
T:
end:


#-----------------------------------------------------------
#2. Partitions whose parts lie in given residue classes mod a
#-----------------------------------------------------------

IsParMod:=proc(L,a,A) local i:
for i from 1 to nops(L) do
 if not member(L[i] mod a,A) then
  RETURN(false):
 fi:
od:
true:
end:

ParMod:=proc(n,a,A) local S,T,s:
S:=Par(n): T:={}:
for s in S do
 if IsParMod(s,a,A) then
  T:=T union {s}:
 fi:
od:
T:
end:


#-----------------------------------------------------------
#3. OEIS sequences
#-----------------------------------------------------------

SeqSD:=proc(N,d) local n:
[seq(nops(SuperDistinctPars(n,d)),n=0..N)]:
end:

SeqPM:=proc(N,a,A) local n:
[seq(nops(ParMod(n,a,A)),n=0..N)]:
end:

#SeqSD(15,2);
#SeqPM(15,5,{1,4});

#Both give the same sequence:
#[1,1,1,1,2,2,3,3,4,5,6,7,9,10,12,14]

#Hence both are OEIS sequence A003114.
#So:
# {nops(SuperDistinctPars(n,2))} = A003114
# {nops(ParMod(n,5,{1,4}))}     = A003114


#-----------------------------------------------------------
#4. Number of standard Young tableaux of shape L
#-----------------------------------------------------------

NuSYT:=proc(L) local i,k,L1,ans:
option remember:

k:=nops(L):

if k=0 then
 RETURN(1):
fi:

ans:=0:

for i from 1 to k-1 do
 if L[i]>L[i+1] then
  L1:=[op(1..i-1,L),L[i]-1,op(i+1..k,L)]:
  ans:=ans+NuSYT(L1):
 fi:
od:

if L[k]>1 then
 L1:=[op(1..k-1,L),L[k]-1]:
else
 L1:=[op(1..k-1,L)]:
fi:

ans:=ans+NuSYT(L1):

ans:
end:


#-----------------------------------------------------------
#5. conjecture for NuSYT([a,b]), a>=b>=0
#-----------------------------------------------------------

#Conjecture:
#NuSYT([a,b]) = binomial(a+b,b)-binomial(a+b,b-1)
#


#-----------------------------------------------------------
#6. conjecture for NuSYT([a,b,c]), a>=b>=c>=0
#-----------------------------------------------------------

#Conjecture:
#NuSYT([a,b,c]) =
#factorial(a+b+c)*(a-b+1)*(a-c+2)*(b-c+1)/
#(factorial(a+2)*factorial(b+1)*factorial(c))


# End