Help:=proc(): print(`NN(v,C), DecodeT(q,n,C), RLC1(q,M,d), RLC(q,n,d) `):end:


#NN(v,C): Given a vector v  and a code (a subset of Fqn(q,n)) finds the set of nearest neighbors of v. Try:
#C:=GRC(2,7,3);v:=RV(2,7); NN(2,v,C);
NN:=proc(v,C) local cha,rec,i:
cha:={C[1]}:
rec:=HD(C[1],v):

for i from 2 to nops(C) do
 if HD(v,C[i])=rec then
   cha:=cha union {C[i]}:
 elif HD(v,C[i])<rec then
   rec:=HD(v,C[i]):
  cha:={C[i]}:
 fi:
od:
cha:
end:

#DecodeT(q,n,C): Given q code C subset of Fqn(q,n) outputs the decoding table
DecodeT:=proc(q,n,C) local T,S,v:
S:=Fqn(q,n):
for v in S do
 T[v]:=NN(v,C)[1]:
od:
op(T):
end:

#RLC1(q,M,d): Given a current generator matrix with minimal distance  d tries to extend it. Try:
#RLC1(2,[[1,0$6]],3);

RLC1:=proc(q,M,d) local n,A,c,M1:
n:=nops(M[1]):

A:=Fqn(q,n) minus LtoC(q,M):

for c in A do
 M1:=[op(M),c]:
 if MinW(q,M1)=d then
  RETURN(M1):
 fi:
od:
FAIL:

end:

#RLC(q,n,d): A random linear code over GF(q)^n with mininal distance d
RLC:=proc(q,n,d) local M,M1:
 M:=[[1$d,0$(n-d)]]:
M1:=RLC1(q,M,d):
while M1<>FAIL do
 M:=M1:
M1:=RLC1(q,M,d):
od:
M:
end: