z=x+I y;zbar=x-I y

f=(z^3/zbar^2//Expand)

u=FullSimplify[(f+Conjugate[f])/2,Assumptions->(x∈Reals&&y∈Reals&&x≠0&&y≠0)]

v=FullSimplify[(f-Conjugate[f])/(2 I),Assumptions->(x∈Reals&&y∈Reals&&x≠0&&y≠0)]

ux=D[u,x]
uy=D[u,y]
vx=D[v,x]
vy=D[v,y]

Limit[ux/.y->0,x->0]==Limit[vy/.x->0,y->0]

Limit[vx/.y->0,x->0]==-Limit[uy/.x->0,y->0]

However, f(z)=u(x,y)+i v(x,y), is not holomorphic! So what’s going on?

If we view the variable in which we are not taking the derivative of u as already “fixed” at our chosen value (here, y=0) before we take that derivative, we get a different value than if we had come in from some other direction.

That is, the derivative of the partially-applied function u(x,0) with respect to x, evaluated at x=0, (which is what the above Cauchy Riemann equations are apparently “satisfied” by) is not the limit of the derivative of u(x,y) with respect to x, at x=0, as we approach y=0,.

TraditionalForm[Style[RowBox[{SubscriptBox[RowBox[{"[",RowBox[{FractionBox["∂","∂x"],"u(x,0)"}],"]"}],"x = 0"],"≠",UnderscriptBox["lim",RowBox[{"y","→","0"}]],SubscriptBox[RowBox[{"(","[",RowBox[{FractionBox["∂","∂x"],"u(x,y)"}],"]"}],"x = 0"],")"}] //DisplayForm,Large,FontFamily->"Marion"]]

This is a plot of (Subscript[u, x])(x,y):=(∂/(∂x))u(x,y), with slices of constant y given the same color.

Plot3D[ux,{x,-1,1},{y,-1,1},PlotPoints->200,AxesLabel->Automatic,ColorFunction->(Hue[#2+0.5,0.6,1]&),Mesh->False]

The following is a vertical slice of the above plot at the corresponding color; that is, it’s a plot of (Subscript[u, x])(x,y) with respect to x, with y determined by the slider position. The color reflects where we are in the above plot.

With[{ux=ux},Manipulate[Plot[ux,{x,-1,1},PlotRange->{-5,5},PlotStyle->{Hue[y/2,1-0.8Abs[y],1]}],{y,-1,1}]]

Note the behavior at y=0,: (Subscript[u, x])(x,y) appears to become 1 at x=0 instead of 5! This equals (Subscript[v, y])(x,y) evaluated the analogous way: differentiating with respect to y after setting x=0.