Help:=proc(): print(`SU(m,p)`): end:

#SU(m,p): simulating an extemeley rish averse player in the Shepp Urn
#Try:
#SU(m,p);
SU:=proc(m,p) local i,m1,p1,r:
m1:=m:
p1:=p:

# What is (p - p1) - (m - m1)?
# p - m is the value if we have to go all the way.
# Well, p - p1 is the number of plus balls we've drawn.
# m - m1 is the number of minus balls we've drawn.
# So (p - p1) - (m - m1) measures our current winnings.
# So, we stop as soon as we get at least p - m, which is what would happen if
# we played all the way.
for i from 1 while (p-p1)-(m-m1)<p-m do
 r:=rand(1..m1+p1)():

  if r<=m1 then
   m1:=m1-1:
  else
   p1:=p1-1:
 fi:

od:

[m1,p1,i-1]:

end:

# The expected duration of the risk-adverse gambler drawing from an (m,
# p)-Shepp urn.
# (The risk-adverse gambler stops drawing as soon as he obtains a value of g,
# or if he cannot improve his value.)
E := proc(m, p)
    ExpD(m, p, p - m):
end:

# The expected duration of the risk-adverse gambler drawing from Shepp's urn
# given that his goal is g and his current value is 0.
# (The risk-adverse gambler stops drawing as soon as he obtains a value of g,
# or if he cannot improve his value.)
ExpD := proc(m, p, g)
    option remember:
    if g <= 0 then
        # Gamber is done.
        0
    elif m = 0 then
        # Gambler will draw until he reaches his goal.
        min(g, p)
    elif p = 0 then
        # Gambler cannot possibly improve his standing.
        0
    else
        # Gambler draws randomly and evaluates his position.
        m / (m + p) * ExpD(m - 1, p, g + 1) + p / (m + p) * ExpD(m, p - 1, g - 1) + 1:
    fi:
end:

# > E(100, 110);
# memory used=4.9MB, alloc=40.3MB, time=0.07
#                   33683086189085193138363517127662830063471100444206895955179886
#                   --------------------------------------------------------------
#                    297474726318397739666969118328344655976262651151936062181333
#
# > evalf(%);
#                                             113.2300771