Help:=proc(): print(` Nor1(L), LD(L), SimBay(Pri,Lik,N) , Bay(Pri,Lik,N) , RSgM(N,L) `): end:



Nor1:=proc(L): L/add(L):end:

#LD(L): Inputs a finite discrete prob. distribution 
LD:=proc(L) local L1,N,i,ra,r,j:
L1:=Nor1(L):


L1:=L1*lcm(seq(denom(L1[i]),i=1..nops(L1)) ):
N:=add(L1):
r:=rand(1..N)():

for i from 1 while add(L1[j],j=1..i)<r do od:
i:

end:

#SimBay(Pri,Lik,N): Inputs a finite prob. dist. Pri, such that Pr(X=i)=Pri[i] and a list of the same length such that
#for some event Pr(Success|X=i)=Lik[i], finds the posterior prob. distibution of that event happened by doing it
#N times.
SimBay:=proc(Pri,Lik,N) local co,i,r,s:

for i from 1 to nops(Pri) do
 co[i]:=0:
od:

for i from 1 to N do

r:=LD(Pri):

s:=LD([Lik[r],1-Lik[r]]):

if s=1 then
 co[r]:=co[r]+1:
fi:

od:

Nor1([seq(co[r],r=1..nops(Pri))]):

end:




#Bay(Pri,Lik,N): Inputs a finite prob. dist. Pri, such that Pr(X=i)=Pri[i] and a list of the same length such that
#for some event Pr(Success|X=i)=Lik[i], finds the posterior prob. distibution of that event happened using Bayes' rule
Bay:=proc(Pri,Lik) local i:
Nor1([seq(Pri[i]*Lik[i],i=1..nops(Pri))]):
end:



#Code by Victoria Chayes
with(LinearAlgebra): with(Statistics):  
RSgM:=proc(N,L) local X: X:=RandomVariable(ProbabilityTable(L)):convert(Sample(X,N),list): end: