#C5.txt: Feb. 4, 2016 
Help:=proc(): print(`F(n), SF(N),T(N) , ST(N),  GP1(L,n,d), GP(L,n) `): end:

#F(n): the Fibonacci nunber F(n)
F:=proc(n)  option remember:
if n=0 or n=1 then
 n:
else
 F(n-1)+F(n-2):
fi:

end:

#SF(N): the sequence of first N Fibonacci numbers starting at n=1
SF:=proc(N) local n:
 [seq(F(n),n=1..N)]:
end:

#T(n): the Tribonacci nunber F(n)
T:=proc(n)  option remember:
if n=1 or n=2 or n=3 then
 1:
else
 T(n-1)+T(n-2)+T(n-3):
fi:

end:

#ST(N): the sequence of first N Fibonacci numbers starting at n=1
ST:=proc(N) local n:
 [seq(T(n),n=1..N)]:
end:

#GP1(L,n,d): inputs a sequence of rational numbers, a symbol n, and a non-neg.
#integer d, outputs a polynomial p(n) such that p(i)=L[i] for all i from 1 to nops(L)
GP1:=proc(L,n,d) local i,a,p,var, var1, eq:

if nops(L)<d+3 then
 print(`Make the list longer`):
 RETURN(FAIL):
fi:

p:=add(a[i]*n^i, i=0..d):

var:={ seq(a[i],i=0..d)}:

eq:={seq( subs(n=i, p)=L[i],i=1..d+3)}:

var1:=solve(eq,var):

if var1=NULL then

 RETURN(FAIL):
fi:


 p:=subs(var1,p):

if {seq(subs(n=i,p)-L[i],i=1..nops(L))}={0} then
 p:
else
 FAIL:
fi:

end:


#GP(L,n): tries to guess a polynomial of degree<=nops(L)-3 in n fitting L
GP:=proc(L,n) local d,p:

for d from 0 to nops(L)-3 do
 p:=GP1(L,n,d):
 if p<>FAIL then
   RETURN(p):
 fi:
od:

FAIL:

end: