Help:=proc(): print(` IsNormal(x,K,d) , Ch(d,k), IsNormalL(L,d) `): end:

#IsNormal(x,K,d): Inputs a real number x (given in terms of
#known constants, a lagre positive integer K, and a base d
#outputs a list of how many 0's, how many 1's, ..., how many d-1-s
IsNormal:=proc(x,K,d) local x1,L,z,f,i:

x1:=trunc(x*(d^K)):

L:=convert(x1,base,d):

f:=add(z[L[i]],i=1..nops(L)):

[seq(coeff(f,z[i],1),i=0..d-1)]:

end:

#Champernowne constant base d up to d^k-1: obsolete thanks to John Chiarelli
ChOld:=proc(d,k) local L,i,n,L1:

L:=[]:

for i from 1 to k do
 for n from d^(i-1) to d^i-1 do
   L1:=convert(n,base,d):

   L:=[op(L), op(L1)]:
 od:
od:
L:
end:


#Champernowne constant base d up to d^k-1
Ch:=proc(d,k) local L,n,L1:

L:=[]:

 for n from 1 to d^k-1 do
   L1:=convert(n,base,d):

   L:=[op(L), op(L1)]:
 od:

L:
end:

#IsNormalL(L,d): Inputs a list L  base d
#outputs a list of how many 0's, how many 1's, ..., how many d-1-s
IsNormalL:=proc(L,d) local z,f,i:


f:=add(z[L[i]],i=1..nops(L)):

[seq(coeff(f,z[i],1),i=0..d-1)]:

end: