#Feb. 16, 2015, C8.txt, Why you should not gamble!
Help:=proc(): print(`CT(p), GRv(N,a,p), GR(N,a,p) `): 
print(`GRsim(N,a,p,K) , PrE(N,p)`):
end:

#CT(p): inputs a rational prob. p, and outputs
#+1 with prob. p and -1 with prob. 1-p 
CT:=proc(p) local n,d,ra:
n:=numer(p):
d:=denom(p):
ra:=rand(1..d)():

if ra<=n then
 1:
else
 -1:
fi:

end:


#GRv(N,a,p): Verbose version
#simulating, verbosely, a gambler who enters
#a casino with a dollars where the stakes are always 1 dollar,
#and at each round wins a dollar with prob. p
#and has to pay a dollar with prob. 1-p
GRv:=proc(N,a,p) local t, c,tos:
c:=a:

if p<1/2 then
 print(`You stupidly enter the casino with`, a, `dollars `):
 print(`hoping to exit with the max`, N, `dollars `):
elif p=1/2 then
print(`You enter the casino with`, a, `dollars `):
 print(`hoping to exit with the max`, N, `dollars `):
elif p>1/2 then

print(`You wisely enter the casino with`, a, `dollars `):
 print(`hoping to exit with the max`, N, `dollars `):
fi:

for t from 1 while (c>0 and c<N) do
tos:=CT(p):
c:=c+tos:

 print(`At the`, t, `-th toss you got`, tos, `and now your`):
 print(`capital is`, c):
od:

t:=t-1:

if c=0 then
 print(`Ha Ha, you are now broke! Serves you right`):
 print(`not only that, you wasted`, t, `tosses `):
elif c=N then

 print(`Congratulations you are now rich!, can you spare me`):
 print(`some change `):
 print( ` only that, it only took you`, t, `tosses `):
else
 print(`You fell asleep at the bar `):


fi:

end:

#GR(N,a,p): terse version
#simulating, verbosely, a gambler who enters
#a casino with a dollars where the stakes are always 1 dollar,
#and at each round wins a dollar with prob. p
#and has to pay a dollar with prob. 1-p
#returns 0,TIMEitTOOK if you are broke
#or 1,TIMEitTOOK
GR:=proc(N,a,p) local t, c,tos:
c:=a:



for t from 1 while (c>0 and c<N) do
tos:=CT(p):
c:=c+tos:

 
od:

t:=t-1:

if c=0 then
 
0,t:

elif c=N then

 1,t:
else
 
 
fi:

end:

#GRsim(N,a,p,K): the gamler goes to the casino K
#times and does GR(N,a,p)
GRsim:=proc(N,a,p,K) local w,d,i,g:

 w:=0:
 d:=0:

 for i from 1 to K do
  g:=GR(N,a,p):
  w:=w+g[1]:
  d:=d+g[2]:
 od:

evalf(w/K),evalf(d/K):

end:

#PrE(N,p): inputs the max capital, and a prob. p
#and outputs a list of length N-1 whose a-th entry is
#the EXACT probability of exiting a winner (with N dollars)
#provided you entered with a dollars
PrE:=proc(N,p) local P,eq,var,i:

var:={seq(P[i],i=1..N-1)}:
eq:={seq(P[i]=p*P[i+1]+(1-p)*P[i-1],i=1..N-1)}:
eq:=subs({P[0]=0,P[N]=1},eq):
var:=solve(eq,var):

[ seq(subs(var,P[i]),i=1..N-1)]:

end: