#March 2, 2015, C12.txt, the special case of the special case of
#the special case of Finance, that nevertheless is very important
#and will be used again and again later

Help:=proc(): 
print(` OPscr(S0,u,d,r,T,Cu,Cd), OP(S0,u,d,r,T,Cu,Cd)`):
print(`ExpBuyer(S0,u,d,r,T,Cu,Cd,q), ExpSeller(S0,u,d,r,T,Cu,Cd,q)`):
print(`MM(S0,u,d,r,T,Cu,Cd)`):
end:

#The price of an option to buy a stock, currently
#costing S0 dollars, and after T units of time
#the stock is either S0*u, or S0*d, and the interest rate is
#r (compounded continuously),
#d<exp(r*T)<u
#Cu:= the contingent claim if the stock went up (now it costs S0*u)
#Cd:= "        wentdown (not it costs S0*d)
#Call option Cu=u*S0-K, Cd=0 
#Put option: Cu=0, Cd=K-S0*d
#also returns the amount of stock to buy in order to
#realize this price
OPscr:=proc(S0,u,d,r,T,Cu,Cd) local x1,x2,P,var,eq:

#x1,x2 is a portfolio: x1 Goverment bonds and x2 units of stock
#Value of the portolio if the stock went up
#x1*exp(r*T)+x2*u*S0>=Cu

#Value of the portolio if the stock went down
#x1*exp(r*T)+x2*d*S0>=Cd

eq:={x1*exp(r*T)+x2*u*S0=Cu,x1*exp(r*T)+x2*d*S0=Cd}:
var:={x1,x2}:

var:=solve(eq,var):

x1:=subs(var,x1):
x2:=subs(var,x2):

P:=normal(x1+x2*S0):

P,x2:

end:

OP:=proc(S0,u,d,r,T,Cu,Cd) local P,x2:
P:=(exp(r*T)*Cd-Cd*u-exp(r*T)*Cu+Cu*d)/(exp(r*T)*(d-u)): 
x2:=(Cd-Cu)/(S0*(d-u)):

factor(coeff(P,Cu,1)*exp(r*T))*(exp(-r*T)*Cu)+
factor(coeff(P,Cd,1)*exp(r*T))*(exp(-r*T)*Cd),x2:
end:

#The expected gain to the buyer of the option
#if she believes that the probability of the stock going up is q
ExpBuyer:=proc(S0,u,d,r,T,Cu,Cd,q) local P:
P:=OP(S0,u,d,r,T,Cu,Cd)[1]:
#prob. q, she would get Cu*exp(-r*T)-P
#prob. 1-q she would get Cd*exp(-r*T)-P

q*(Cu*exp(-r*T)-P)+(1-q)*(Cd*exp(-r*T)-P):

end:



#The expected gain to the seller of the option
#if she believes that the probability of the stock going up is q
#following the do nothing portoflio
ExpSeller:=proc(S0,u,d,r,T,Cu,Cd,q) local P:
P:=OP(S0,u,d,r,T,Cu,Cd)[1]:

q*(P-Cu*exp(-r*T))+ (1-q)*(P-Cd*exp(-r*T)):

end:

#MM(S0,u,d,r,T,Cu,Cd): the two coefficients in front
#of today's value of the two contingent claim
MM:=proc(S0,u,d,r,T,Cu,Cd) local P:
P:=(exp(r*T)*Cd-Cd*u-exp(r*T)*Cu+Cu*d)/(exp(r*T)*(d-u)): 


[factor(coeff(P,Cu,1)*exp(r*T)),factor(coeff(P,Cd,1)*exp(r*T))]:
end:


#0Pnice(S0,u,d,r,T,Cu,Cd):the same as OP but using
#the martingale property that the future price of S0
#is the expected value of the stocks in time T
OPnice:=proc(S0,u,d,r,T,Cu,Cd) local q:
#q: probability of the stock going up so it has the martingale property
q:=solve(q*u+(1-q)*d=exp(r*T),q):

q*Cu*exp(-r*T)+(1-q)*Cd*exp(-r*T):

end: